FormatDateTime()

说明：

返回表达式，此表达式已被格式化为日期或时间。

原型：

FormatDateTime(Date[, NamedFormat])

参数:

Date 必选项。要被格式化的日期表达式。
NamedFormat 可选项。指示所使用的日期/时间格式的数值，如果省略，则使用 vbGeneralDate。

设置:

    NamedFormat 参数可以有以下值：
    常数      值     描述
    vbGeneralDate     0     显示日期和/或时间。如果有日期部分，则将该部分显示为短日期格式。如果有时间部分，则将该部分显示为长时间格式。如果都存在，则显示所有部分。
    vbLongDate     1     使用计算机区域设置中指定的长日期格式显示日期。
    vbShortDate     2     使用计算机区域设置中指定的短日期格式显示日期。
    vbLongTime     3     使用计算机区域设置中指定的时间格式显示时间。
    vbShortTime     4     使用 24 小时格式 (hh:mm) 显示时间。

实例，测试时间：2010-4-28 20:16：

    函数       返回值
    FormatDateTime(date,0) 2010-4-28
    FormatDateTime(date,1) 2010年4月28日
    FormatDateTime(date,2) 2010-4-28
    FormatDateTime(date,3) 0:00:00
    FormatDateTime(date,4) 00:00
    FormatDateTime(time,0) 20:15:56
    FormatDateTime(time,1) 1899年12月30日
    FormatDateTime(time,2) 1899-12-30
    FormatDateTime(time,3) 20:15:56
    FormatDateTime(time,4) 20:15
    FormatDateTime(Now,0) 2010-4-28 20:17:24
    FormatDateTime(Now,1) 2010年4月28日
    FormatDateTime(Now,2) 2010-4-28
    FormatDateTime(Now,3) 20:17:24
    FormatDateTime(Now,4) 20:17

Asp格式化日期，Asp时间日期补位，原创万能补位函数：

<%
Public Function ForMatDate(DateAndTime, Para) '格式化日期(日期时间,格式)
Dim Y, M, D, H, F, S
IF Not ISNumeric(Para) Or Not ISDate(DateAndTime) Then Exit Function
Y = CStr(Year(DateAndTime))
M = CStr(Month(DateAndTime)):IF Len(M) = 1 Then M = "0" & M
D = CStr(Day(DateAndTime)):IF Len(D) = 1 Then D = "0" & D
H = CStr(Hour(DateAndTime)):IF Len(H) = 1 Then H = "0" & H
F = CStr(Minute(DateAndTime)):IF Len(F) = 1 Then F = "0" & F
S = CStr(Second(DateAndTime)):IF Len(S) = 1 Then S = "0" & S
Select Case Para
    Case "0"
        ForMatDate = Y & "-" & M & "-" & D & " " & H & ":" & F & ":" & S
    Case "1"
        ForMatDate = Y & "-" & M & "-" & D & " " & H & ":" & F
    Case "2"
        ForMatDate = Y & "-" & M & "-" & D
    Case "3"
        ForMatDate = Y & "/" & M & "/" & D
    Case "4"
        ForMatDate = Y & "年" & M & "月" & D & "日"
    Case "5"
        ForMatDate = M & "-" & D & " " & H & ":" & F
    Case "6"
        ForMatDate = M & "/" & D
    Case "7"
        ForMatDate = M & "月" & D & "日"
    Case "8"
        ForMatDate = Y & "年" & M & "月"
    Case "9"
        ForMatDate = Y & "-" & M
    Case "10"
        ForMatDate = Y & "/" & M
    Case "11"
        ForMatDate = right(Y,2) & "-" &M & "-" & D & " " & H & ":" & F
    Case "12"
        ForMatDate = right(Y,2) & "-" &M & "-" & D
    Case "13"
        ForMatDate = M & "-" & D
    Case Else
        ForMatDate = DateAndTime
End Select
End Function
Response.Write ForMatDate(Now,"1")
%>

【Asp技巧】Asp格式化日期/时间日期补位

文章目录

FormatDateTime()